Shocking The Web CD-ROM/SHOCK_CD.ISO/mac/Chapter Tutorials/DevGallery/Headbone/Source/DRESSVEL.DIR/00092.ls

Text File | 1996-04-30 | 2.5 KB | 77 lines

on dragSprite vSprite
  set vDiffH to the mouseH - the locH of sprite vSprite
  set vDiffV to the mouseV - the locV of sprite vSprite
  repeat while the stillDown
    set locVH to the mouseH - vDiffH
    set locVV to the mouseV - vDiffV
    set the locH of sprite vSprite to locVH
    set the locV of sprite vSprite to locVV
    updateStage()
  end repeat
end

on snapTo vSprite, vOrigH, vOrigV
  global gElroySprite
  set vfSnapped to 0
  if sprite vSprite intersects gElroySprite then
    set vfSnapped to snapToElroy(vSprite, vOrigH, vOrigV)
  end if
  if vfSnapped = 0 then
    set the locH of sprite vSprite to vOrigH
    set the locV of sprite vSprite to vOrigV
    updateStage()
  end if
end

on snapToElroy vClosetSprite, vOrigH, vOrigV
  global gElroySprite, glClosetItemSprites
  set vfSnapped to 0
  set vWearSprite to getSpriteFromPageType()
  if the visible of sprite vWearSprite then
    set the visible of sprite vWearSprite to 0
    repeat with vSpriteInCloset in glClosetItemSprites
      if the castNum of sprite vSpriteInCloset = the castNum of sprite vWearSprite then
        set the visible of sprite vSpriteInCloset to 1
        exit repeat
      end if
    end repeat
  end if
  updateStage()
  set the visible of sprite vClosetSprite to 0
  set the locH of sprite vClosetSprite to vOrigH
  set the locV of sprite vClosetSprite to vOrigV
  set the castNum of sprite vWearSprite to the castNum of sprite vClosetSprite
  set the locH of sprite vWearSprite to the locH of sprite gElroySprite
  set the locV of sprite vWearSprite to the locV of sprite gElroySprite
  set the visible of sprite vWearSprite to 1
  updateStage()
  set vfSnapped to 1
  return vfSnapped
end

on getSpriteFromPageType
  global gCurPage, gHatSprite, gGlovesSprite, gShoesSprite, gJacketSprite, gShirtSprite, gPantsSprite, gcHATS, gcSHIRTS, gcPANTS, gcSHOES, gcJACKETS
  if gCurPage <= gcHATS then
    set vWearSprite to gHatSprite
  else
    if gCurPage <= (gcHATS + gcSHIRTS) then
      set vWearSprite to gShirtSprite
    else
      if gCurPage <= (gcHATS + gcSHIRTS + gcPANTS) then
        set vWearSprite to gPantsSprite
      else
        if gCurPage <= (gcHATS + gcSHIRTS + gcPANTS + gcSHOES) then
          set vWearSprite to gShoesSprite
        else
          if gCurPage = (gcHATS + gcSHIRTS + gcPANTS + gcSHOES + gcJACKETS) then
            set vWearSprite to gJacketSprite
          else
            set vWearSprite to gGlovesSprite
          end if
        end if
      end if
    end if
  end if
  return vWearSprite
end